Bring your data to live!

use util;
type Sensor {
  id: String;
  values: nodeTime<Measurement>;
}
type Measurement {
  temperature: float;
  humidity: float;
}
// global variable, serve as graph entry-point
var sensor_index: nodeGeo<Sensor>;
fn fill() {
  var rand = Random::new();
  sensor_index ?= nodeGeo<Sensor>::new(); // init if null
  for (var nb_sensors = 0; nb_sensors < 100; nb_sensors++) {
    var sensor = Sensor {
      id: "sensor_${nb_sensors}",
      values: nodeTime<Measurement>::new()
    };
    var lat = rand.uniformf(-90.0, 90.0);
    var lng = rand.uniformf(-180.0, 180.0);
    sensor_index.set(geo::new(lat, lng), sensor);
    for (var nb_val = 0.0; nb_val < 100_000; nb_val++) {
      var measurement = Measurement {
        temperature: rand.uniformf(-30.0, 30.0),
        humidity: rand.uniformf(0.0, 100.0)
      };
      var t = time::new(nb_val as int, DurationUnit::microseconds);
      sensor.values.setAt(t, measurement);
    }
  }
}
@expose
fn temperature_std(center: geo, radius: float, t: time): float {
  var gaussian = Gaussian {};

  var circle = GeoCircle::new(center, radius);
  for (sensor_location, sensor in sensor_index) {
    if (circle.contains(sensor_location)) {
      gaussian.add(sensor.values.resolveAt(t)?.temperature);
    }
  }
  return gaussian.std()!!;
}